*  JieJie Microelectronics P-Spice Model Library
*  Filename	      :    JMSH0403AGQ_P v.20230410.txt
*  Product Name   :    JMSH0403AGQ (PDFN5x6-8L)
*  Configuration:	:    Single N-channel Device
*  Data Sheet Rev.:    1.1
*  Release Date	:    Apr11, 2023
*  Junction Temp (Tj): -40C ~ 175C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, Jiangsu JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH0403AGQ D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.0013
RS S 3 1E-006
RG G 17 3.8
CGS 3 G 1.48E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00392*(TEMP-25))+((-3.31517E-6)*(TEMP-25)^2)}
Gtemp 1 3  VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.7)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1e-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cds D 3 Cbreak 2.25152E-9
.MODEL Cbreak CAP (C=1 VC1= -0.04081 VC2 = 4.96762E-4)

.model NMOS NMOS
+LEVEL = 3       
+VMAX = 8.544074E6           ETA = 3.468048E-5     
+VTO = 3.53866               TOX = 1.494289E-12           NSUB = 9.066291E18  
+KP = 107.05716              U0 = 1.843859E-4               KAPPA = 1.48895E-2   
+GAMMA = 8.489458E-3           PHI = 0.62945           THETA = -1.124431E-7          
+DELTA = 75.427519         

.model DCGD D
+CJO = 2.1e-10               VJ = 13              M = 1.6   


.model DSUB D
+IS = 3.893198E-14           N = 1.024961         RS = 1.920394E-3    
+BV = 48                     xti = 0.024084      
                  
.model DLIM D
+IS = 1E-4  
.ends JMSH0403AGQ

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************


